여행사진보정

라이트룸에서 webp 로 변환하기

니파 2025. 8. 15. 16:56

어도비 라이트룸 클래식 14.4 버전에서도 여전히 webp 로 내보내기는 지원하지 않습니다.

플러그인을 알아보니, 한번에 10장 내보내기 제한이 있다던가 그런 관계로, 배치 파일을 이용해서 변환하는 방법을 만들었습니다.

 

니파가 이용하는 라이트룸 파일 내보내기 설정

저 같은 경우는 raw 촬영을 보정 후 tiff 파일로 내보낸 뒤, 그걸 다시 webp 로 변환하도록 했습니다.

jpg로 내보내는게 편하긴 한데, 이게 손실 압축 파일이다보니 최종 결과물이 webp 라고 할 때, 손실이 두 번 일어나게 되더군요.

일단 webp 로 만드는 목적 자체가 jpg 대비, 가벼운 용량을 목적으로 하기에, 무손실 버전은 생각하지 않았습니다.

 

제가 이용하는 배치파일은 아래와 같습니다.

@echo off
rem 원본 JPG/TIFF → WebP 변환 후 GPS/EXIF 메타데이터 복사

setlocal enabledelayedexpansion
chcp 65001 > nul

rem --- 환경 변수 설정 ---
set "CWEBP=C:\Utils\libwebp-1.6.0-windows-x64\bin\cwebp.exe"
set "EXIFTOOL=C:\Utils\exiftool-13.33_64\exiftool.exe"
set "SOURCE_FOLDER=C:\Users\nipa0711\Desktop\보정"
set "QUALITY=100"

echo.
echo %SOURCE_FOLDER% 폴더의 이미지를 WEBP로 변환하고 원본 이미지를 삭제합니다...
echo 변환을 시작합니다...
echo.

rem --- 이미지 파일만 반복 처리 (이미지 파일만 가져옴) ---
for %%F in ("%SOURCE_FOLDER%\*.jpg" "%SOURCE_FOLDER%\*.jpeg" "%SOURCE_FOLDER%\*.png" "%SOURCE_FOLDER%\*.bmp" "%SOURCE_FOLDER%\*.gif" "%SOURCE_FOLDER%\*.tif" "%SOURCE_FOLDER%\*.tiff") do (
    rem WEBP 파일의 전체 경로 설정
    set "output_path=%%~dpF%%~nF.webp"
    
    rem WEBP 파일이 존재하지 않는 경우에만 변환 진행 (최적화)
    if not exist "!output_path!" (
        echo "%%F"를 "!output_path!"로 변환 중...
        
        rem 1단계 : 이미지 변환
        "%CWEBP%" -preset photo -af -q %QUALITY% "%%F" -o "!output_path!"
        rem 고화질용 "%CWEBP%" -preset photo -af -q %QUALITY% "%%F" -near_lossless 80 -o "!output_path!"


        rem 2단계 : 메타데이터 복사 (GPS, EXIF 전체)
        "%EXIFTOOL%" -TagsFromFile "%%~F" "-all:all>all:all" "!output_path!" -overwrite_original
        
        rem 3단계 : 변환 성공 시 원본 파일 삭제
        if exist "!output_path!" (
            echo 원본 파일 삭제: "%%F"...
            del "%%F"
        )
    )
)

echo.
echo 모든 이미지 변환 및 원본 파일 삭제가 완료되었습니다.
echo.
pause

convert_webp.bat
0.00MB

ChatGPT 의 도움을 받아서 만든 스크립트였는데, 삽질은 좀 했었습니다.

처음에는 GPS같은 메타데이터가 생략되어서, 그것도 포함되게 만들었습니다.

 

먼저 위 배치파일은 두 개의 프로그램을 요구합니다.

cwebp 와 exiftool 입니다.

cwebp :  Index of downloads.webmproject.org/releases/webp

전 libwebp-1.6.0-windows-x64 를 이용하고 있습니다.

exiftool : ExifTool by Phil Harvey

64-bit: exiftool-13.33_64.zip (10.8 MB) 윈도우용을 이용했습니다.

set "CWEBP=C:\Utils\libwebp-1.6.0-windows-x64\bin\cwebp.exe"
// 자신의 cwebp.exe 위치로 변경해주세요.

set "EXIFTOOL=C:\Utils\exiftool-13.33_64\exiftool.exe"
// 자신의 exiftool.exe 파일 위치로 변경해주세요.

set "SOURCE_FOLDER=C:\Users\nipa0711\Desktop\보정"
// 자신이 이용하는 라이트룸 내보내기 폴더 위치로 변경해주세요.
// 전 바탕화면에 보정이라는 폴더를 이용하고 있습니다.

배치파일 코드에서 위의 3개의 경로를 수정해주셔야 합니다.

업로드된 코드는 제 환경에서만 작동합니다.

 

저 같은 경우는 배치파일을 c 드라이브에 넣어놓고, 바탕화면으로 내보내기로 바로가기를 만들어서 이용하고 있습니다.

본 포스팅의 배치파일을 이용한 webp 변환 결과 화면

실행하면 이런식으로 됩니다.

 

raw to jpg

jpg - 1.9MB (RAW -> JPG)

raw -> tiff -> webp test image

webp - 958.1KB (RAW -> TIFF -> WEBP)

 

webp 가 용량대비 화질이 우수하다고 해서, 이제는 webp 로 블로그에 업로드 해볼려고 합니다.

 

저작자표시 비영리 동일조건 (새창열림)